vec3 doLighting( const vec3 pos, const vec3 normal, const vec3 albedo, const float specMask, const float viewDist)
{
   vec3 light = lightPos.xyz - pos;
   
   // Distance attenuation
   float lightDist = length( light ) / lightPos.w;
   float att = 1.0 - lightDist * lightDist;
   light = normalize( light );
   
   // Spotlight falloff
   float angle = dot( lightDir, -light );
   if( angle > lightCosCutoff )
      att *= (angle - lightCosCutoff) / 0.2;
   else
      att = 0.0;
      
   // Half lambert lighting
   float NdotL = dot( normal, light );
   float diffuse = NdotL * 0.5 + 0.5;
   diffuse = diffuse * diffuse;      
   
   // Final color
   vec3 col = albedo * lightColor * (diffuse + 0.3)*att;     // (Diffuse & ambient) color
   
   // Shadow
   if( NdotL > 0.0 && att > 0.0 )
   {   
      mat4 lightMat;
      if( viewDist < shadowSplitDists.x ) lightMat = shadowMats[0];
      else if( viewDist < shadowSplitDists.y ) lightMat = shadowMats[1];
      else if( viewDist < shadowSplitDists.z ) lightMat = shadowMats[2];
      else lightMat = shadowMats[3];
      
      vec4 projShadow = lightMat * vec4( pos, 1.0 );
      projShadow.z = lightDist;
      projShadow.xy /= projShadow.w;
      
      float shade = PCF( projShadow );
      
      // Specular
      vec3 eye = normalize( viewer - pos );
      vec3 refl = reflect( -light, normal );
      float spec = pow( clamp( dot( refl, eye ), 0.0, 1.0 ), 8.0 ) * specMask;
      col += vec3( 0.3, 0.3, 0.4 ) * spec * att * shade;

      col *= max( 0.5, shade );
   }
   
   return col;
}